We-Mod-It | Das Forum von Moddern für Modder

Quellcode

/*
Arduino Tutorial 5.1 - Temperaturmessung mit einem 10kO NTC Wiederstand

by Scynd 2015

In diesem Tutorial geht es darum, die Temperatur mit einem 10kO NTC zu messen.
*/


// Konstanten
const long interval = 1000;       	// Interval wie oft die Temperatur abgefragt wird (milliseunden)
const int AbfrageZahl = 5;        	// Je mehr abfragen, desto stabiler isr das Ergebnis, dauert aber länger
const int NTC = A0;               	// Pin für den 10kO NTC Wiederstand
const int NTCNominal = 4700;     	// Wiederstand des NTC bei Nominaltemperatur
const int TempNominal = 25;       	// Temperatur bei der der NTC den angegebenen Wiederstand hat
const int BCoefficient = 3950;    	// Beta Coefficient(B25 aus Datenblatt des NTC)
const int SerienWiederstand = 4700;  // Wert des Wiederstands der mit dem NTC in Serie geschalten ist

									 // Variablen
int Abfrage[AbfrageZahl];    	// Array Variable für das Mitteln der Temperatur
float Durchschnitt = 0;      	// Variable für das Mitteln der Temperatur
float Temp;                  	// Variable für die Berechnung der temperatur nach Steinhart
unsigned long letzteMillis = 0;  // Speichert die letzte Zeit (millis) der Temperaturabfrage


void setup() {

	Serial.begin(9600);         	// Setzt die Baudrate für die Ausgabe am Serial Monitor auf 9600
	pinMode(NTC, INPUT);        	// Setzt den Pin des NTC Wiederstands als Eingang
}


void loop() {

	// Erfasst die aktuelle Zeit für den Abfrageinterval
	unsigned long aktuelleMillis = millis();

	// Löst bei erreichen der Intervalzeit die Temperaturberechnung aus
	if (aktuelleMillis - letzteMillis >= interval) {
		// speichert die Zeit der letzten Abfrage
		letzteMillis = aktuelleMillis;
		// Startet die Temperaturerfassungsroutine
		Temperaturberechnung();
	}

	// Ausgabe an den Seriellen Monitor
	Serial.print("Temperatur ");
	Serial.print(Temp);
	Serial.println(" *C");
	delay(1000);
}


void Temperaturberechnung() {

	// Nimmt N Abfragen in einer Reihe, mit einem kurzen delay
	for (int i = 0; i < AbfrageZahl; i++) {
		Abfrage[i] = analogRead(NTC);
		delay(10);
	}

	// Mittelt alle Abfragen
	Durchschnitt = 0;
	for (int i = 0; i < AbfrageZahl; i++) {
		Durchschnitt += Abfrage[i];
	}
	Durchschnitt /= AbfrageZahl;

	// Umwandlung des Wertes in Wiederstand
	Durchschnitt = 1023 / Durchschnitt - 1;
	Durchschnitt = SerienWiederstand / Durchschnitt;

	// Umrechnung aller Ergebnisse in die Temperatur mittels einer Steinhard Berechnung
	Temp = Durchschnitt / NTCNominal; 	// (R/Ro)
	Temp = log(Temp);                 	// ln(R/Ro)
	Temp /= BCoefficient;             	// 1/B * ln(R/Ro)
	Temp += 1.0 / (TempNominal + 273.15); // + (1/To)
	Temp = 1.0 / Temp;                	// Invertieren
	Temp -= 273.15;                   	// Umwandeln in °C
}